Using instr command with “[a-zA-Z]”

Topic

New Reply

Hi!
There ara several frames in my doc. Some of them are pictures and some of them are contain text.
I want to find if it contain text. How should I use the “instr” command?
Thanks in advance.

Code:

Sub LoopFrames()

 Dim frm As Frame

 For Each frm In ActiveDocument.frames
 frm.Select
 hah = frm.Range.Text

********* THIS LINE İS MY PROBLEM****
if instr(hah, “[a-zA-Z]”) >0 Then
‘or I want to do this line
 If hah.Text Like “[a-zA-Z]” = True Then 
*********************************
 MsgBox hah
 End If
 Next frm
 End Sub

Reply | Quote

Replies

Ken,

VBA’s instr function does not support regular expressions.

Maybe someone else knows how to search frames but I’ve drawn a blank.

:cheers:

May the Forces of good computing be with you!

RG

PowerShell & VBA Rule!
Computer Specs

Reply | Quote

Ken,

Ok, I think I’ve got it now:

Code:

Option Explicit

Sub LoopFrames()

   Dim frm As Frame

   For Each frm In ActiveDocument.Frames
     
      If (frm.Range.Find.Execute(findtext:="[a-z,A-Z]", _
              Forward:=True, MatchWildcards:=True)) Then
        MsgBox frm.Range
      End If

   Next frm

End Sub  'LoopFrames

Here’s my test document:
43356-kentestdoc

Running the program produced the two desired msg boxes.

Here’s the Document w/macro:

HTH :cheers:

May the Forces of good computing be with you!

RG

PowerShell & VBA Rule!
Computer Specs

Reply | Quote

A more robust way that takes into account anything that might be counted as text:

Code:

Sub FrameTextTest()
Dim Frm As Frame
For Each Frm In ActiveDocument.Frames
  MsgBox RangeHasText(Frm.Range)
Next
End Sub

Function RangeHasText(Rng As Range) As Boolean
RangeHasText = (Len(Rng.Text) > Rng.InlineShapes.Count)
End Function

Cheers,
Paul Edstein
[Fmr MS MVP - Word]

Reply | Quote

Paul,

If I read your code correctly In-Line Shapes in the frame count as 1 character each?

Neat solution, I’d never have gotten there! :cheers:

May the Forces of good computing be with you!

RG

PowerShell & VBA Rule!
Computer Specs

Reply | Quote

If I read your code correctly In-Line Shapes in the frame count as 1 character each?

Correct. In text terms, they actually express themselves as a /.

Cheers,
Paul Edstein
[Fmr MS MVP - Word]

Reply | Quote

Thanks to both of you.

Reply | Quote